Algoritma BBO (Biogeography-based Optimization)

Algoritma BBO (Biogeography-based Optimization) adalah salah satu algoritma optimasi yang dapat digunakan untuk pengambilan keputusan. Contoh yang dibahas kali ini adalah mengenai pencarian posisi dengan pengembalian nilai fungsi maksimal.
Algoritma ini menggunakan prinsip individu dalam bermigrasi ke tempat lain. Tentu saja tujuan migrasi adalah untuk mencari tempat / habitat yang lebih baik. Dalam kasus ini nantinya setiap individu akan terus menerus melakukan migrasi sampai sudah tidak ditemukan lagi habitat yang lebih baik dari habitat sebelumnya.

Diasumsikan ada sebaran titik 2 dimensi antara -2 sampai dengan 2
Fungsi yang diketahui adalah fungsi Himmelblau, dengan rumus f(x, y) = (x^2+y-11)^2 + (x+y^2-7)^2
Tentukan posisi dimana fungsi tersebut mengembalikan nilai maksimal

Fungsi Himmelblau adalah salah satu fungsi yang dapat digunakan untuk mengoptimasi suatu permasalahan. Fungsi ini memiliki sebuah nilai maksimum pada x = -0.270845, and y = -0.923039 dengan nilai fungsi sebesar f(x,y) = 181.617, dengan asumsi bahwa rentang minimal dan maksimal dari sebaran titik adalah -2 sampai dengan 2

Grafik fungsi Himmelblau yang normal, atau untuk sebaran titik tak terbatas adalah sebagai berikut.

Sedangkan Grafik fungsi Himmelblau untuk sebaran titik dengan rentang minimal -2 dan maksimal 2 adalah sebagai berikut.

Dapat dilihat bahwa pada gambar tersebut, didapatkan area dengan titik tertinggi (berwarna merah) berada pada area x = -0, and y = -1, dimana titik tersebut mengembalikan nilai fungsi tertinggi. Oleh sebab itu digunakan algoritma ini untuk mencari titik di area berwarna merah tersebut.

Sebelum masuk kedalam langkah-langkah pembahasan algoritma, ada beberapa konstanta atau parameter yang harus diketahui, yaitu:
* Tentukan dimensi permasalahan dalam sebuah solusi
Diasumsikan dalam kasus ini, dimensi bernilai 2 karena ada 2 dimensi yang akan dicari solusinya yaitu x dan y

Const dimensi As Integer = 2

* Tentukan posisi minimal dan maksimal dari fungsi yang akan dihitung
Jika tidak ada batasan posisi, tentu saja posisi yang mendekati tak terhingga akan terpilih karena akan mengembalikan nilai fungsi yang sangat besar
Diasumsikan dalam kasus ini, posisi minimal adalah -2, dan posisi maksimal adalah +2

Const minPosisi As Double = -2
Const maksPosisi As Double = +2

* Tentukan jumlah iterasi yang digunakan dalam perhitungan
Diasumsikan dalam kasus ini, jumlah iterasi adalah 500 kali

Const jumlahIterasi As Integer = 500

* Tentukan ukuran populasi yang digunakan dalam perhitungan
Diasumsikan dalam kasus ini, ukuran populasi yang digunakan adalah 25

Const ukuranPopulasi As Integer = 25

* Tentukan rasio individu yang disimpan dalam habitat
Diasumsikan dalam kasus ini, rasio penyimpanan individu adalah 0.2
Kemudian hitung jumlah individu yang disimpan dengan rumus:
nKeep=round(KeepRate*nPop);

Const rasioPenyimpananIndividu As Double = 0.2
Dim jumlahIndividuTersimpan = Math.Round(rasioPenyimpananIndividu * ukuranPopulasi)

* Tentukan alpha, yaitu koefisien untuk menghitung perpindahan individu ke habitat baru
Diasumsikan dalam kasus ini, alpha adalah 0.9

Const alpha As Double = 0.9

* Tentukan probabilitas mutasi individu
Nilai ini nantinya digunakan dalam proses mutasi individu dalam melakukan migrasi
Diasumsikan dalam kasus ini, probabilitas mutasi adalah 0.1

Const probabilitasMutasi As Double = 0.1

Langkah-langkah penggunaan algoritma ini adalah

* Lakukan proses pencarian posisi terbaik
Penjelasan lebih detail tentang fungsi ini dapat dilihat pada penjelasan skrip dibawah ini (poin 1 – 6)

Dim posisiTerbaik() As Double = BBO(dimensi, minPosisi, maksPosisi, jumlahIterasi, ukuranPopulasi, _
									jumlahIndividuTersimpan, alpha, probabilitasMutasi)

Memasuki perhitungan pada fungsi BBO

* Inisialisasi individu yang digunakan sebanyak ukuran populasi

1. Lakukan perulangan sebanyak ukuran populasi (poin 1a – 1b)

For i As Integer = 0 To ukuranPopulasi - 1
. . .

1a. Beri posisi acak pada masing-masing individu sebanyak jumlah dimensi

For j As Integer = 0 To dimensi - 1
	populasi(i).posisi(j) = (maksPosisi - minPosisi) * rnd.NextDouble() + minPosisi
Next

1b. Hitung nilai fungsi pada posisi tersebut
Penjelasan tentang fungsi ini dapat dilihat pada penjelasan skrip dibawah ini

populasi(i).nilaiFungsi = hitungNilaiFungsi(populasi(i).posisi)

* Gunakan fungsi ini untuk menghitung nilai fungsi yang diinginkan
Fungsi yang diketahui adalah fungsi Himmelblau, dengan rumus f(x, y) = (x^2+y-11)^2 + (x+y^2-7)^2

Public Function HitungNilaiFungsi(x1 As Double, y As Double) As Double
	Dim hasil As Double = Math.Pow(x1 * x1 + y - 11, 2) + Math.Pow(x1 + y * y - 7, 2)
	Return hasil
End Function

2. Urutkan populasi berdasarkan nilai fungsi terbaik (tertinggi) ke nilai fungsi terburuk (terendah)

Array.Sort(populasi)

3. Ambil posisi individu pertama sebagai posisi terbaik sementara

Array.Copy(populasi(0).posisi, PosisiTerbaik, dimensi)
nilaiFungsiTerbaik = populasi(0).nilaiFungsi

4. Hitung parameter rasio emigrasi, yang dilambangkan dengan mu
dan parameter rasio imigrasi, yang dilambangkan dengan lambda
rasio emigrasi memiliki nilai sebanyak ukuran populasi,
dengan nilai awal adalah 1, dan akan berkurang secara konstan sampai mencapai angka 0
sedangkan rasio imigrasi adalah kebalikan dari rasio emigrasi
dengan nilai awal adalah 0, dan akan bertambah secara konstan sampai mencapai angka 1

Dim rasio As Double = 1 / (ukuranPopulasi - 1)
Dim mu(ukuranPopulasi - 1) As Double
Dim lambda(ukuranPopulasi - 1) As Double
For i As Integer = 0 To ukuranPopulasi - 1
	mu(i) = 1 - i * rasio
	lambda(i) = i * rasio
Next

5. Tentukan nilai sigma, yaitu 2 persen dari selisih posisi maksimal dan posisi minimal

Dim sigma As Double = 0.02 * (maksPosisi - minPosisi)

* Lakukan proses pencarian posisi terbaik (poin 6)

6. Lakukan proses perhitungan sebanyak jumlah iterasi (poin 6a – 6f)

Dim iterasi As Integer = 0
Do While iterasi < jumlahIterasi
	iterasi += 1
	. . .

6a. Beri nilai awal populasi yang baru dengan menggunakan posisi dan nilai fungsi dari populasi yang ada

Dim populasiBaru() As Individu = populasi.Clone

6b. Lakukan perhitungan pada masing-masing dimensi dalam populasi baru (poin 6b1 - 6b4)

For i As Integer = 0 To ukuranPopulasi - 1
	For j As Integer = 0 To dimensi - 1
	. . .

6b1. Lakukan proses migrasi berikut ini apabila nilai acak kurang dari nilai rasio imigrasi (poin 6b1a - 6b1b)
Karena nilai rasio imigrasi bertambah secara konstan,
maka individu yang mendekati akhir akan memiliki kemungkinan lebih besar untuk mengalami migrasi dibandingkan individu pada bagian awal

If rnd.NextDouble < lambda(i) Then
. . .

6b1a. Tentukan habitat tujuan migrasi individu ini
Teknik yang digunakan adalah teknik Seleksi Roulette (Roulette Wheel Selection)
Habitat tujuan ini tidak boleh sama dengan posisi individu yang sedang dihitung

Dim idxHabitatTerpilih As Integer = i
While idxHabitatTerpilih = i
	idxHabitatTerpilih = RouletteWheelSelection(mu, rnd)
End While

* Gunakan fungsi ini untuk melakukan teknik Seleksi Roulette (Roulette Wheel Selection)
Nilai yang lebih baik akan memiliki kemungkinan yang lebih besar untuk terpilih
Dalam kasus ini, nilai yang dibandingkan adalah nilai rasio emigrasi

Public Function RouletteWheelSelection(ByVal nilai() As Double, ByVal rnd As Random) As Integer
	Dim bobot(nilai.Length - 1) As Double
	Dim totalBobot As Double = 0
	For i As Integer = 0 To bobot.Length - 1
		totalBobot += nilai(i)
		bobot(i) = totalBobot
	Next

	Dim probabilitasKumulatif As Double = rnd.NextDouble * totalBobot
	Dim idxTerpilih As Integer = -1
	For i As Integer = 0 To bobot.Length - 1
		If bobot(i) > probabilitasKumulatif Then
			idxTerpilih = i
			Exit For
		End If
	Next

	Return idxTerpilih
End Function

6b1b. Hitung posisi yang baru dengan rumus:
posisi baru = posisi + alpha * selisih posisi habitat tujuan dengan posisi individu sekarang

populasiBaru(i).posisi(j) = populasi(i).posisi(j) + alpha * (populasi(idxHabitatTerpilih).posisi(j) - populasi(i).posisi(j))

6b2. Lakukan proses mutasi berikut ini apabila nilai acak kurang dari parameter probabilitas mutasi
posisi baru dihitung dengan rumus:
posisi baru = posisi + sigma * distribusi normal acak

If rnd.NextDouble <= probabilitasMutasi Then
	populasiBaru(i).posisi(j) += sigma * HitungDistribusiNormalAcak(rnd)
End If

* Gunakan fungsi ini untuk menghitung distribusi normal acak
Sehingga nilai yang berada ditengah-tengah akan memiliki kemungkinan muncul yang lebih banyak,
dan nilai yang berada dibagian ujung akan memiliki kemungkinan muncul yang lebih sedikit

Public Function HitungDistribusiNormalAcak(ByVal rnd As Random, Optional ByVal mean As Double = 0, Optional ByVal stdDev As Double = 1) As Double
	Dim u1 As Double = rnd.NextDouble()
	Dim u2 As Double = rnd.NextDouble()
	Dim rndStdNormal As Double = Math.Sqrt(-2.0 * Math.Log(u1)) * Math.Sin(2.0 * Math.PI * u2) 'random normal(0,1)
	Dim rndNormal As Double = mean + stdDev * rndStdNormal                                    'random normal(mean, stdDev^2)
	Return rndNormal
End Function

6b3. Jika posisi individu yang baru ternyata diluar batas posisi yang diperbolehkan,
maka kembalikan nilainya agar masuk dalam batas tersebut

If populasiBaru(i).posisi(j) < minPosisi Then
	populasiBaru(i).posisi(j) = minPosisi
ElseIf populasiBaru(i).posisi(j) > maksPosisi Then
	populasiBaru(i).posisi(j) = maksPosisi
End If

6b4. hitung nilai fungsi pada posisi tersebut

populasiBaru(i).nilaiFungsi = hitungNilaiFungsi(populasiBaru(i).posisi)

6c. Urutkan populasi yang baru berdasarkan nilai fungsi terbaik (tertinggi) ke nilai fungsi terburuk (terendah)

Array.Sort(populasiBaru)

6d. Simpan individu terbaik dari populasi yang lama sebanyak parameter jumlah individu tersimpan
Kemudian ganti individu lainnya sesuai dengan individu terbaik pada populasi yang baru

For i As Integer = jumlahIndividuTersimpan To ukuranPopulasi - 1
	populasi(i) = populasiBaru(i - jumlahIndividuTersimpan).Clone
Next

6e. Lakukan pengurutan populasi sekali lagi

Array.Sort(populasi)

6f. Jika nilai fungsi individu terbaik ternyata lebih baik dari nilai fungsi secara umum,
maka ambil posisi terbaik individu tersebut sebagai posisi terbaik

If populasi(0).nilaiFungsi > nilaiFungsiTerbaik Then
	Array.Copy(populasi(0).posisi, PosisiTerbaik, dimensi)
	nilaiFungsiTerbaik = populasi(0).nilaiFungsi
End If

* Agar dapat menjalankan skrip diatas, maka diperlukan sebuah Class Individu untuk menampung semua data posisi dan nilai fungsinya. Deklarasi Class Individu adalah sebagai berikut:

Public Class Individu
    Implements IComparable(Of Individu)
    Implements ICloneable

    Public posisi() As Double
    Public nilaiFungsi As Double

    Public Sub New(ByVal dimensi As Integer)
        Me.posisi = New Double(dimensi - 1) {}
        Me.nilaiFungsi = 0.0
    End Sub
	
	. . .
End Class

Hasil akhir adalah: (klik untuk perbesar gambar)

Contoh modul / source code dalam bahasa VB (Visual Basic) dapat didownload disini:

Jika membutuhkan jasa kami dalam pembuatan program, keterangan selanjutnya dapat dilihat di Fasilitas dan Harga
Jika ada yang kurang paham dengan langkah-langkah algoritma diatas, silahkan berikan komentar Anda.
Selamat mencoba.